$ Define the grid
MESH       GRID.FAC=1.0
MASK       IN.FILE=masks.tl1  PRINT  GRID="Field,Poly"

$ Initialize the structure
INITIALIZE <100>  BORON=1.1E15

$ Boron field implant
IMPLANT    BORON  DOSE=3E12  ENERGY=60  TILT=7  ROTATION=30

$ Field oxidation
DIFFUSION  TIME=5   TEMP=1050  DRYO2
DIFFUSION  TIME=70  TEMP=1050  CONTINUE WETO2 
DIFFUSION  TIME=5   TEMP=1050  CONTINUE DRYO2

$ Field Lithography
DEPOSITION    PHOTORESIST  POSITIVE  THICKNESS=1
EXPOSE     MASK=Field
DEVELOP
ETCH       OXIDE        ISOTROPI  THICKNESS=0.640
ETCH       PHOTORESIST  ALL

$ Gate Oxidation
DIFFUSION  TIME=30   TEMP=1103  DRYO2

$ Poly Deposition
DEPOSITION   POLYSILICON  THICK=0.213

$ Gate Lithography
DEPOSITION    PHOTORESIST  POSITIVE  THICKNESS=1
EXPOSE     MASK=Gate
DEVELOP
ETCH       POLYSILICON  ISOTROPI THICKNESS=0.213
ETCH       OXIDE        ISOTROPI THICKNESS=0.092
ETCH       PHOTORESIST  ALL

$Spin on Glass, Pre-deposition, and Drive in.
DEPOSITION PHOTORESIST PHOSPHORUS=1e25 THICKNESS=1 
DIFFUSION  TIME=5    TEMP=1050
ETCH PHOTORESIST ALL
METHOD COMPRESS
DIFFUSION  TIME=12   TEMP=1050 WETO2
DIFFUSION  TIME=25   TEMP=1050 CONTINUE INERT

$Contact Hole Lithography
DEPOSITION    PHOTORESIST  POSITIVE  THICKNESS=1
EXPOSE     MASK=Contact
DEVELOP
ETCH       OXIDE        ISOTROPI THICKNESS=0.180
ETCH       PHOTORESIST  ALL

$Metal Layers
DEPOSITION   ALUMINUM   THICKNESS=1.6
DEPOSITION    PHOTORESIST  POSITIVE  THICKNESS=1
EXPOSE     MASK=Metal
DEVELOP
ETCH       ALUMINUM     ISOTROPI THICKNESS=1.84
ETCH       PHOTORESIST  ALL 

$ Save structure
SAVEFILE   OUT.FILE=OUTPUT

$ Plot the initial NMOS structure
SELECT     Z=LOG10(BORON)  TITLE="Final MOSFET Structure"
PLOT.2D    Y.MAX=2.0  

$ Color fill the regions
COLOR     SILICON  COLOR=7
COLOR     OXIDE    COLOR=5
COLOR     POLY     COLOR=3
COLOR     ALUM     COLOR=2

$ Plot contours of boron
FOREACH    X  (15 TO 20 STEP 0.5)
  CONTOUR    VALUE=X  LINE=5  COLOR=2
END

$ Replot boundaries
PLOT.2D    ^AX  ^CL

$ Print doping information under field oxide
SELECT     Z=DOPING
PRINT.1D   X.VALUE=4.5  X.MAX=3

savefile out.f=structure.tif tif