$ EE130 Fall 2005 MOSFET Project: TSUPREM4 DECK

$ This is the process simulation input deck. Tsuprem4 allows the
$ device engineer to simulate actual process flows to fabricate the 
$ intended device. This can then be imported into MEDICI to simulate IV.

$ The following lines of code simulate the fabrication steps (i.e,
$ oxidation, implant, diffusion, deposition, etc) to create an nMOSFET
$ at the 45 nm technology node. Note that this transistor has a physical 
$ gate length Lg of 18 nm!

$ Defining some of the variables of interest for mesh generation
$ --------------------------------------------------------------------
$ All simulations require a mesh of points where the governing equations 
$ are solved for numerically.
$ --------------------------------------------------------------------

 define lgate .018
 define contactdistance .05
 define contactwidth .05
 define boundary .18
 define aligntol .03

$ Adjust the coarse/fineness of the grid
 mesh grid.fac=1.0

$ Define the grid in terms of the variables
$ Staring with the x lines first
$ ------------------------------------------------------------------
$ Here the mesh is generated by specifying coordinates and spacings.
$ ------------------------------------------------------------------

 line x loc=-@{boundary} spac=.05
 line x loc=-((@{lgate}/2)+@{contactdistance}+@{contactwidth}) spac=.03
 line x loc=-((@{lgate}/2)+@{contactdistance}) spac=.02
 line x loc=-(@{lgate}/2) spac=@{lgate}/20
 line x loc=(@{lgate}/2) spac=@{lgate}/20
 line x loc=(@{lgate}/2)+@{contactdistance} spac=.02
 line x loc=(@{lgate}/2)+@{contactdistance}+@{contactwidth} spac=.03
 line x loc=@{boundary} spac=.05

$ Now we will do the y lines next
 line y loc=0 spac=.002
 line y loc=.25 spac=.05

$ Initialize structure (P-type <100> Silicon)
$ --------------------------------------------------------------------
$ This specifies a P-type Si substrate of doping 1e15 cm-3 with wafer 
$ surface of oreination <100>
$ --------------------------------------------------------------------

 initialize <100> boron=1e15

$ Now we starting the process flow

$ STEP 1:
$ Vt adjust implant to raise the threshold voltage. A sacrificial
$ screening oxide is used place dopants right at interface.
$ NOTE: change implant dose from 4.5e13 to 4.5Xe13 where X is the 
$       last digit in your SID
 deposit oxide thickness=0.01 
 implant boron dose=4.5e13 energy=5 impl.tab=boron
 etch oxide all

$ STEP 2:
$ Gate oxidation growth
$ Specify native oxide on Si surface to be 1 Angstrom
$ grow thin oxide with target EOT ~ 1.0 nm
$ NOTE: change oxidation time from 14 to 14.Y where Y is the last digit of 
$       your partner's SID
 method compress dy.oxide=.00002
 ambient initial=0.0001
 DIFFUSION time=14 temp=800 DRYO2

$ STEP 3:
$ Deposit polysilicon
 deposit material=polysili thickness=0.06

$ STEP 4:
$ Etching polysilicon to define gate of Lg = 18 nm
 deposit material=photoresist thickness=1.0 spaces=5
 etch photoresist left p1.x=-(@{lgate}/2) p2.y=0
 etch photoresist right p1.x=(@{lgate}/2) p2.y=0
 etch polysili old.dry thickness=0.06
 etch photoresist all

$ STEP 5:
$ Angled Halo implant to reduce Vt roll-off and leakage currents
$ Note: change implant dose from 1e13 to 1.0Ze13 where Z is the difference
$       between the last digits of you and your partners SID.(abs value)
 implant boron dose=1e13 energy=11 tilt=14 rotation=180 impl.tab=boron

$ STEP 6:
$ LDD implant for shallow junction formation
 deposit material=oxide thick=0.005 spaces=15
 implant arsenic dose=1e14 energy=5 impl.tab=arsenic
 etch material=oxide old.dry thickness=0.005

$ STEP 7:
$ Spacer formation and Deep Source/Drain implant
 deposit material=oxide thick=0.025
 etch material=oxide old.dry thickness=0.025
 implant arsenic dose=1e15 energy=10 impl.tab=arsenic

$ STEP 8:
$ High temperature aneal for dopant activation
  diffusion time=0.167 temperat=1000 inert

$ STEP 9:
$ Deposit LTO for Passivation (Low Temperature Oxide)
  deposit material=oxide thickness=0.25

$ STEP 10:
$ Contact hole etching
 deposit photoresist thick=1 space=5
 etch photoresist start x=-((@{lgate}/2)+@{contactdistance}) y=-3
 etch continue x=-((@{lgate}/2)+@{contactdistance}) y=1
 etch continue x=-((@{lgate}/2)+@{contactdistance}+@{contactwidth}) y=1
 etch done x=-((@{lgate}/2)+@{contactdistance}+@{contactwidth}) y=-3
 etch photoresist start x=(@{lgate}/2)+@{contactdistance} y=-3
 etch continue x=(@{lgate}/2)+@{contactdistance} y=1
 etch continue x=(@{lgate}/2)+@{contactdistance}+@{contactwidth} y=1
 etch done x=(@{lgate}/2)+@{contactdistance}+@{contactwidth} y=-3
 etch material=oxide old.dry thickness=0.4
 etch photoresist all

$ STEP 11:
$ Deposit Interconnect Aluminum
 deposit material=aluminum thickness=0.1

$ STEP 12:
$ Metal etching
 deposit photoresist thick=1 space=5
 etch photoresist start x=-((@{lgate}/2)+@{contactdistance}-@{aligntol}) y=-3
 etch continue x=-((@{lgate}/2)+@{contactdistance}-@{aligntol}) y=1
 etch continue x=(@{lgate}/2)+@{contactdistance}-@{aligntol} y=1
 etch done x=(@{lgate}/2)+@{contactdistance}-@{aligntol} y=-3
 etch material=aluminum old.dry thickness=0.2
 etch photoresist all

$ Define electrodes for import into MEDICI simulator
 electrode name=gate   x=0
 electrode name=drain  x=(@{lgate}/2)+@{contactdistance}+(@{contactwidth}/2)
 electrode name=source x=-(@{lgate}/2)-@{contactdistance}-(@{contactwidth}/2)
 electrode name=substrate bottom

$ Save structure to load into MEDICI
 savefile out.file=EE130nmos.str medici poly.ele

$ Final 2D plot of the device showing doping contours
 select z=log10(arsenic)
 plot.2d y.max=0.1 y.min=-0.08

 color polysili color=2
 color silicon color=7
 color oxide color=5
 color photoresist color=6
 color aluminum color=4

 foreach x (15 to 21 step 1)
    contour value=x line=5 color=3
 end

 select z=log10(boron)
 plot.2d ^clear y.max=0.1 y.min=-0.08

 foreach x (15 to 21 step 1)
    contour value=x line=5 color=4
 end

$ Print thickness of deposited or grown layers
$ Pay attention to the gate oxide thickness
 select z=1
 print layers x.v=0

 quit